function fish_mode_prompt --description 'Displays the current mode'
    # Do nothing if not in vi mode
    if test "$fish_key_bindings" = fish_vi_key_bindings
        or test "$fish_key_bindings" = fish_hybrid_key_bindings
        switch $fish_bind_mode
            case default
                set_color --bold --reverse normal
                echo ' N '
            case insert
                set_color --bold --reverse brblue
               echo ' I '
            case replace_one
                set_color --bold --reverse brblue
                echo ' I '
            case replace
                set_color --bold --reverse brblue
                echo ' I '
            case visual
                set_color --bold --reverse brgreen
                echo ' V '
        end
        set_color normal
    end
end
